「もうすぐ犯行記念日」（講談社，日本推理作家協会編）の序文である．

『記念日をめぐる不思議なクイズがある．何の記念日でも構わないけど，個人に関わる一番ポピュラーな記念日ということなら，誕生日だろう．

　

　もし，ここに３０人の構成員からなる集団があって，この中に誕生日の一致するペアが一組以上いるかどうか？　このギャンブルをやるとしたら，あなたはどちらに賭けるだろう．誕生日なんてめったに一致するものじゃないよなあ．まして構成員はたった３０人である．一も二もなくペアは一組もいないほうに賭けるのではあるまいか？

　

　だが，お立ち会い．これがそうでもない．特定の人を選び，その人と誰かの誕生日が一致する確率は確かに小さい．そう，１／３６５である．３０人の集団の中で一致する確率はすこぶる小さいけど，このことと「３０人の中の誰かと誰かが一致する」こととはまるで違う．

　

　確率計算はややこしくて，文筆家に向かないから省略するけど，疑う人は数学に堪能な人に尋ねて下さい．構成員が２３人と越えるあたりで一致する確率が５０％を越える．３０人もいようものなら７０％位の確率になる．まして，４０人，５０人ならばさらに高い．構成員３〜４０人の職場を想定したとき，誕生日の一致する確率はまずいるものと考えたほうが妥当である．』

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝

　

　このクイズは数多くの本で取り扱われた有名なものであるが，確かに，少なくとも２人同じ誕生日の人がいる確率の大きさには驚かされる．これを読んだ植木嬢（職場の同僚）が早速小生に疑問を投げかけてきた．ひとつには，この数字が女の直感に反するというものであり，もうひとつには，実際の計算方法を見るまではどうしても合点がいかないというものであった．

　

　この序文には，おしつけがましく結果だけを書いてあるが，実際問題として，確率計算になれていないと，式の誘導は難しいだろう．とりあえず，信じるものは救われる．ホレ信じなさい．というわけであるが，天下り式で我慢できないかたは，以下の説明を参照しながら誘導を試みられたい．

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝

　

　このクイズのトリックは，２人が同じ誕生日である確率は，１／３６５と小さいけれども，３０人もいれば，３０人の中から２人を選び出す組合せ数（３０，２）は，３０×２９／２＝４３５通りもあることである．これであれば，同じ誕生日に生まれたペア数の平均値は４３５／３６５となるから，一組以上のペアができると期待できるのである．一般に，１年はｄ日とし，構成員をｎ人とするとペア数の期待値はｎ（ｎ−１）／２ｄになっていることに注意されたい．

　

　式を誘導するため，次のような定式化をおこなってみよう．

１番目の人と２番目の人が異なる誕生日である確率は１−１／ｄである．

また，３番目の人が１番と２番の人と誕生日が異なる確率は，２番目の人は１番目の人と異なる日に生まれたとして，１−２／ｄである．

したがって，ｎ人全員が異なる誕生日である確率ｐnは，

　　ｐn＝（１−１／ｄ）×（１−２／ｄ）×・・・×（１−（ｎ−１）／ｄ）

となる．求めたい確率ｐは少なくとも２人同じ誕生日の人がいる確率であるから，

　　ｐ＝１−ｐn

　

　電卓を使ったとしても，この計算はわずらわしいので，ＢＡＳＩＣプログラムを示しておく．

　

1000 '

1010 ' *** solve birthday problem ***

1020 '

1030 DEFDBL A-H,L-Z

1040 D=365

1050 '

1060 INPUT "n=";N

1070 DIM PN(N)

1080 '

1090 GOSUB *PAIR

1100 '

1110 '

1120 PRINT "p=";P

1130 PRINT "q=";Q

1140 '

1150 END

1160 '

1170 *PAIR:

1180 PN=1

1190 FOR I=1 TO N-1

1200　 PN=PN*(1-I/D)

1210 NEXT I

1220 P=1-PN

1230 '

1240 C=N*(N-1)/2

1250 Q=1-EXP(-C/D)

1260 RETURN

　

　ｄ＝３６５について，ｎ＝２３では求める確率は０．５０７３，ｎ＝３０では０．７１，ｎ＝４０では０．８９にもなる．したがって，ｎ＝３０〜４０だったら少なくとも２人は同じ誕生日であるほうに賭けるほうが賢明であることがわかる．

　

　また，ｎがｄに比べて小さければ，テイラー展開より

　　１−ｋ／ｄ〜ｅｘｐ（−ｋ／ｄ）

　　Π（１−ｋ／ｄ）〜ｅｘｐ（−Σｋ／ｄ）

Σｋ＝ｎ（ｎ−１）／２であるから，

　　ｐ〜１−ｅｘｐ（−ｎ（ｎ−１）／２ｄ）

となる．

　

　ここで，先ほど説明したペア数の期待値ｎ（ｎ−１）／２ｄが再登場しているが，ペア数の分布は複雑であっても，その平均は単純であり，この近似計算はペア数の分布を平均ｎ（ｎ−１）／２ｄのポアソン分布で近似したものと考えることができる．電卓計算にはポアソン近似のほうが向いていて，たとえば，ｎ＝２３，ｄ＝３６５であれば，ｐ〜０．５０００が得られ，真の値０．５０７３のよい近似となっていることが理解される．

　

　

ｎ　　　　２０　　２３　　３０　　４０　　５０

正確な値　0.4114　0.5073　0.7063　0.8912　0.9704

近似値　　0.4058　0.5000　0.6963　0.8820　0.9651

　

　

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝

　

　医療関係者の中には数学の専門家も感心するほど数学に堪能な方もおられるが，そのような方は多くはないし，医療と研究に追われて，このような問題を吟味する暇もなく，よくわからないまま過ごすことのほうが普通であろう．残念ながら女の直感は外れてしまったが，ともあれ，瑣末な問題にも興味を示した植木嬢の好奇心は見習いたいものである．

　

　これでＱ＆Ａが済み，やっと肩の荷がおりたといいたいところであるが，小生の悪い癖で，問題を拡張したり，新しい計算方法をひねりだすまでは，時のたつのも忘れ，考え始めるとやめられなくなってしまう．まったく損な性分であるし，病気一歩手前の凝り性といわれても仕方ないとさえと思うが，次に，少なくとも１組の同じ誕生日の３人がいる確率を考えてみよう．

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝

　

　トリオの場合は，正確な確率を求めることは難しいので，近似計算のほうを最初に掲げておく．ペアの場合の議論と同様，

３人の組合せ数（ｎ，３）はｎ（ｎ−１）（ｎ−２）／６，

３人が同じ誕生日であることは確率１／ｄ2で起きるから，その期待値は

　　ｎ（ｎ−１）（ｎ−２）／６ｄ2

となる．したがって，平均ｎ（ｎ−１）（ｎ−２）／６ｄ2のポアソン分布で近似すると，

　　ｐ〜１−ｅｘｐ（−ｎ（ｎ−１）（ｎ−２）／６ｄ2）

　

　この近似によれば，同じ誕生日のトリオがいる確率を１／２以上にするためには８４人が必要であるが，正確には最低でも８８人は必要である．以下，正確な値を得る方法を示すが易しくはない．発想の転換が必要とされる．

　

　ｎ人の中に同じ誕生日のトリオがいない確率ｐnは，同じ誕生日のペアがｋ組（ｋ＝０，・・・，ｎ／２）いるが，トリオがいない確率ｐn,kの和となる．

　　ｐn＝Σｐn,k

　多項分布により，

　　ｐn,k＝Σｎ！／ｉ1！・・・ｉd！（１／ｄ）^n

であるが，分数の分母のｉは２の個数がｋ，１の個数がｎ−２ｋ，残りが０であるから，

　　ｐn,k＝（ｄ，ｋ）（ｄ−ｋ，ｎ−２ｋ）ｎ！／２^k（１／ｄ）^n

　このことから，漸化式

　　ｐn,k＝（ｎ−２ｋ＋２）（ｎ−２ｋ＋１）／２ｋ（ｄ−ｎ＋ｋ）ｐn,k-1

を得ることができる．求める確率ｐは１−ｐnである．

　

　ＢＡＳＩＣプログラムとその計算結果を示そう．

　

1000 '

1010 ' *** solve birthday problem ***

1020 '

1030 DEFDBL A-H,L-Z

1040 D=365

1050 '

1060 INPUT "n=";N

1070 DIM PN(N)

1080 '

1090 GOSUB *PAIR

1100 GOSUB *TRIO

1110 '

1120 PRINT "p=";P

1130 PRINT "q=";Q

1140 PRINT "r=";R

1150 END

1160 '

1170 *PAIR:

1180 PN=1

1190 FOR I=1 TO N-1

1200　 PN=PN*(1-I/D)

1210 NEXT I

1220 P=1-PN

1230 '

1240 C=N*(N-1)/2

1250 Q=1-EXP(-C/D)

1260 RETURN

1270 '

1280 *TRIO:

1290 IF PN=0 THEN GOSUB *TRIO.0:GOTO 1350

1300 PN(0)=PN

1310 FOR J=1 TO INT(N/2)

1320　 PN(J)=PN(J-1)*(N-2*J+2)*(N-2*J+1)/2/J/(D-N+J)

1330　 IF PN(J)<0 THEN PN(J)=0

1340 NEXT J

1350 '

1360 PN=0

1370 FOR J=0 TO INT(N/2)

1380　 PN=PN+PN(J)

1390 NEXT J

1400 P=1-PN

1410 '

1420 C=N*(N-1)*(N-2)/6

1430 Q=1-EXP(-C/D/D)

1440 '

1450 W0=(1-1/D)^N

1460 W1=N/D*(1-1/D)^(N-1)

1470 W2=N*(N-1)/2/D/D*(1-1/D)^(N-2)

1480 WW=D*(1-W0-W1-W2)

1490 R=1-EXP(-WW)

1500 RETURN

1510 '

1520 *TRIO.0:

1530 FFF=D:GOSUB *FACTORIAL:L1=GGG

1540 FFF=N:GOSUB *FACTORIAL:L2=GGG

1550 L7=N*LOG(D)

1560 '

1570 M=INT(N/2)

1580 MAX=0:IF MAX<(N-D) THEN MAX=N-D

1590 '

1600 FOR J=0 TO INT(N/2)

1610　 GOSUB *TRIO.SUB

1620　 IF PN(J)<>0　AND J>=MAX THEN M=J:GOTO 1640

1630 NEXT J

1640 '

1650 FOR J=M+1 TO INT(N/2)

1660　 PN(J)=PN(J-1)*(N-2*J+2)*(N-2*J+1)/2/J/(D-N+J)

1670　 IF PN(J)<0 THEN PN(J)=0

1680 NEXT J

1690 RETURN

1700 '

1710 *TRIO.SUB:

1720 IF N-2*J<0 THEN 1800

1730 IF D-N+J<0 THEN 1800

1740 FFF=J　　:GOSUB *FACTORIAL:L3=GGG

1750 FFF=N-2*J:GOSUB *FACTORIAL:L4=GGG

1760 FFF=D-N+J:GOSUB *FACTORIAL:L5=GGG

1770 L6=J*LOG(2)

1780 LP=L1+L2-L3-L4-L5-L6-L7

1790 PN(J)=EXP(LP)

1800 RETURN

1810 '

1820 ' ** 階乗計算 **

1830 '

1840 *FACTORIAL:

1850 IF FFF=0 THEN GGG=0:RETURN

1860 GGG=0

1870 FOR I=1 TO FFF

1880 GGG=GGG+LOG(I)

1890 NEXT I

1900 RETURN

　

　

ｎ　　　　６０　　８０　　８８　　１００　１２０

正確な値　0.2072　0.4182　0.5111　0.6459　0.8280

近似値１　0.2265　0.4603　0.5612　0.7029　0.8785

近似値２　0.2043　0.4095　0.4996　0.6305　0.8099

　

　

　前述の近似値（１）

　　ｐ〜１−ｅｘｐ（−ｎ（ｎ−１）（ｎ−２）／６ｄ2）

の誤差は小さくなく，精度に問題がある．近似値（２）はポアソン近似の改良版であるが，近似値（１）より真の値に接近していることがわかる．その求め方は説明しなかったが，演習問題として残しておくことにする．

　

---